dxy

现今，随着移动存储器的越来越广泛的应用，伴随着这些移动设备的存储器而产生的病毒也越来越多。这些病毒无非就是通过Windows的Autorun机制来传播。于是我做了一个Auorun病毒清除工具。

1.本程序通过批处理来写。代码如下：

@echo off
color 2f
title Autorun 病毒清除工具 By Phexon
:clearauto
cls
echo.
echo Autorun 病毒清除工具
echo 制作：Phexon
echo.
echo 本程序运行后自动清除每个盘符下面的Autorun病毒
echo 本程序原理是基于读取每个盘符下的Autorun.inf相关字段
echo.
echo [1] 仅仅删除每个盘下的 Autorun 病毒
echo [2] 删除每个盘符下的 Autorun 病毒并且建立同名免疫目录
echo [3] 禁用系统的 Autorun 机制以避免 Autorun 病毒的再次感染
echo [0] 退出
echo.
set /p clearslt= 请输入您的选择(1/2/3/0)
if "%clearslt%"=="1" goto clearauto1
if "%clearslt%"=="2" goto clearauto2
if "%clearslt%"=="3" goto clearauto3
if "%clearslt%"=="0" exit

:clearauto1
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
for /f "tokens=2 delims==" %%b in (%%a:\autorun.inf) do del /a /f /q "%%a:\%%b" >nul 2>nul
del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
for /f "tokens=2 delims==" %%b in (%%a:\autorun.inf) do del /a /f /q "%%a:\%%b" >nul 2>nul
del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
)
cls
echo Autorun 病毒清除完毕，任意键返回……
pause>nul
goto clearauto

:clearauto2
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
for /f "tokens=2 delims==" %%b in (%%a:\autorun.inf) do del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
for /f "tokens=2 delims==" %%b in (%%a:\autorun.inf) do del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
)
cls
echo Autorun 病毒清除并免疫完毕，任意键返回……
pause>nul
goto clearauto

:clearauto3
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
net stop ShellHWDetection >nul 2>nul
sc config ShellHWDetection start= disabled >nul 2>nul
cls
echo 相关服务已停止并禁用，任意键返回……
pause >nul
goto clearauto

1.将文件保存为autorunkill.bat。
2.程序原理是通过读取每个盘符下的Autorun.inf里面的相关字段来识别病毒体，并删除。
3.程序目前可以做到跳过光驱等只读设备的扫描。只对硬盘，U盘等可移动设备进行扫描。
4.程序不仅仅是删除Autorun.inf。而是首先查看Autorun.inf相关字段。然后根据字段指向的文件进行删除。然后再删除Autorun.inf。


编辑：ache